! $Id: lmdz_cloud_optics_prop.f90 6176 2026-04-18 20:17:55Z evignon $
MODULE lmdz_cloud_optics_prop
  PRIVATE

  LOGICAL, SAVE :: first_first = .TRUE.
  !$OMP THREADPRIVATE(first_first)

  PUBLIC cloud_optics_prop, cloud_optics_prop_post

CONTAINS

!=================================================================================================        
SUBROUTINE cloud_optics_prop_post()
  USE lmdz_cloud_optics_prop_ini, ONLY: novlp
  USE lmdz_cloud_optics_prop_ini, ONLY: first
  IMPLICIT NONE

  IF (first_first) THEN
    IF (ANY(first)) THEN
      IF (novlp==1) THEN
        WRITE (*, *) 'Hypothesis on cloud overlap: MAXIMUM_ &
                &                                             &
                &                                          RANDOM'
        first_first = .FALSE.
      ELSEIF (novlp==2) THEN
        WRITE (*, *) 'Hypothesis on cloud overlap: MAXIMUM'
        first_first = .FALSE.
      ELSEIF (novlp==3) THEN
        WRITE (*, *) 'Hypothesis on cloud overlap: RANDOM'
        first_first = .FALSE.
      ENDIF
    ENDIF
  ENDIF

END SUBROUTINE cloud_optics_prop_post


!=================================================================================================
SUBROUTINE cloud_optics_prop(klon, klev, paprs, pplay, temp, radocond, picefra, pclc, &
    pcldtau, pclemi, pch, pcl, pcm, pct, radocondwp, xflwp, xfiwp, xflwc, xfiwc, &
    mass_solu_aero, mass_solu_aero_pi, pcldtaupi, distcltop, temp_cltop, re, fl, reliq, reice, &
    reliq_pi, reice_pi, scdnc, cdnc, cdnc_pi, cldncl, reffclwtop, lcc, reffclws, &
    reffclwc, cldnvi, lcc3d, lcc3dcon, lcc3dstra, icc3dcon, icc3dstra,  & 
    icefrac_optics, dNovrN, ptconv,rnebcon, ccwcon)

  USE lmdz_cloud_optics_prop_ini , ONLY : flag_aerosol, ok_cdnc
  USE lmdz_cloud_optics_prop_ini , ONLY : lunout
  USE lmdz_cloud_optics_prop_ini , ONLY : bl95_b0, bl95_b1
  USE lmdz_cloud_optics_prop_ini , ONLY : latitude_deg
  USE lmdz_cloud_optics_prop_ini , ONLY : iflag_t_glace
  USE lmdz_cloud_optics_prop_ini , ONLY : cdnc_max, cdnc_max_m3
  USE lmdz_cloud_optics_prop_ini , ONLY : cdnc_min, cdnc_min_m3
  USE lmdz_cloud_optics_prop_ini , ONLY : thres_tau, thres_neb
  USE lmdz_cloud_optics_prop_ini , ONLY : prmhc, prlmc
  USE lmdz_cloud_optics_prop_ini , ONLY : coef_froi, coef_chau
  USE lmdz_cloud_optics_prop_ini , ONLY : seuil_neb
  USE lmdz_cloud_optics_prop_ini , ONLY : t_glace_min_old, t_glace_max_old
  USE lmdz_cloud_optics_prop_ini , ONLY : k_ice0, df
  USE lmdz_cloud_optics_prop_ini , ONLY : rg, rd, rpi
  USE lmdz_cloud_optics_prop_ini , ONLY : rad_chau1, rad_chau2, iflag_rei
  USE lmdz_cloud_optics_prop_ini , ONLY : ok_icefra_lscp, rei_max, rei_min
  USE lmdz_cloud_optics_prop_ini , ONLY : rei_coef, rei_min_temp
  USE lmdz_cloud_optics_prop_ini , ONLY : zepsec, novlp, iflag_ice_thermo, ok_new_lscp
  USE lmdz_cloud_optics_prop_ini , ONLY : first, iflag_cdreff
  



  IMPLICIT NONE
  ! ======================================================================
  ! Authors: Z.X. Li (LMD/CNRS) date: 19930910
  !          O.Boucher (LMD/CNRS) mise a jour en 201212
  !          I. Musat (LMD/CNRS) : prise en compte de la meme hypothese 
  !                              de recouvrement pour les nuages que pour 
  !                              le rayonnement rrtm via le parametre
  !                               novlp de radopt.h : 20160721
  !          L.Fairheard, E.Vignon, JB Madeleine, L. Raillard, A. Idelkadi
  !          M. Coulon-Decorzens: replayisation of the routine + cleaning
  !                               and commentaries
  !          "atelier optics of clouds": careful reading and comments 
  !                                   things to address -> see ?aoc
  !          E. Vignon: comments + cleaning + structuration
  !
  ! Aim: compute condensates' optical properties
  !      (cloud optical depth,) and emissivity 
  ! ======================================================================
  
  ! List of arguments
  !------------------

  ! ?aoc all the pi arguments should be optional

  ! input:
  INTEGER, INTENT(IN) :: klon, klev      ! number of horizontal and vertical grid points
  REAL, INTENT(IN) :: paprs(klon, klev+1)! pressure at bottom interfaces [Pa]
  REAL, INTENT(IN) :: pplay(klon, klev)  ! pressure at the middle of layers [Pa]
  REAL, INTENT(IN) :: temp(klon, klev)   ! temperature [K]
  REAL, INTENT(IN) :: radocond(klon, klev) ! cloud condensed water seen by radiation [kg/kg]
  REAL, INTENT(IN) :: picefra(klon,klev) ! ice fraction in clouds from large scale condensation scheme [-]
  REAL, INTENT(IN) :: rnebcon(klon,klev) ! convection cloud fraction [-]
  REAL, INTENT(IN) :: ccwcon(klon,klev)  ! condensed water from deep convection [kg/kg]
  REAL, INTENT(IN) :: mass_solu_aero(klon, klev)    ! total mass concentration for all soluble aerosols [ug m-3]
  REAL, INTENT(IN) :: mass_solu_aero_pi(klon, klev) ! - (pre-industrial value)
  REAL, INTENT(IN)  :: dNovrN(klon)         ! enhancement factor for cdnc
  REAL, INTENT(OUT) :: distcltop(klon,klev) ! distance from large scale cloud top [m] ?aoc
  REAL, INTENT(OUT) :: temp_cltop(klon,klev)! temperature at large scale cloud top [K] ?aoc

  LOGICAL, INTENT(IN) :: ptconv(klon, klev) ! flag for grid points affected by deep convection

  ! inout:
  REAL, INTENT(INOUT) :: pclc(klon, klev) ! cloud fraction for radiation [-] ?aoc
  REAL, INTENT(INOUT) :: icefrac_optics(klon, klev)! ice fraction in clouds seen by radiation [-]


  ! out:
  ! only diagnostics:
  REAL, INTENT(OUT) :: pct(klon)      ! 2D total cloud cover [-]
  REAL, INTENT(OUT) :: pcl(klon)      ! 2D low cloud cover [-]
  REAL, INTENT(OUT) :: pcm(klon)      ! 2D mid cloud cover [-]
  REAL, INTENT(OUT) :: pch(klon)      ! 2D high cloud cover [-]
  REAL, INTENT(OUT) :: radocondwp(klon) ! total condensed water path (seen by radiation) [kg/m2]
  REAL, INTENT(OUT) :: xflwp(klon)    ! liquid water path (seen by radiation) [kg/m2]
  REAL, INTENT(OUT) :: xfiwp(klon)    ! ice water path (seen by radiation) [kg/m2]
  REAL, INTENT(OUT) :: xflwc(klon, klev) ! liquid water content seen by radiation [kg/kg]
  REAL, INTENT(OUT) :: xfiwc(klon, klev) ! ice water content seen by radiation [kg/kg]
  REAL, INTENT(OUT) :: re(klon, klev) ! cloud droplet effective radius multiplied by fl
  REAL, INTENT(OUT) :: fl(klon, klev) ! xliq * rneb, denominator to re; fraction of liquid water clouds
                                      ! introduced to avoid problems in the averaging of the output
                                      ! water clouds within a grid cell
 
  ! diagnostics or properties if one uses oldrad
  REAL, INTENT(OUT) :: pcldtau(klon, klev) ! cloud optical depth [m]
  REAL, INTENT(OUT) :: pclemi(klon, klev) ! cloud emissivity [-]
  REAL, INTENT(OUT) :: pcldtaupi(klon, klev) ! pre-industrial value of cloud optical depth, ie.
                                             ! values of optical depth that does not account
                                             ! for aerosol effects on cloud droplet radius [m]
  REAL, INTENT(OUT) :: scdnc(klon, klev)   ! cloud droplet number concentration, mean over the whole mesh [m-3]
  REAL, INTENT(OUT) :: cdnc(klon, klev)    ! cloud droplet number concentration [m-3] 
  REAL, INTENT(OUT) :: cdnc_pi(klon, klev) ! cloud droplet number concentration [m-3], pre-industrial
  REAL, INTENT(OUT) :: cldncl(klon)        ! cloud droplet number concentration at top of cloud [m-3]
  REAL, INTENT(OUT) :: reffclwtop(klon)    ! effective radius of cloud droplet at top of cloud [m] 
  REAL, INTENT(OUT) :: lcc(klon)           ! liquid Cloud Content at top of cloud [kg/kg]
  REAL, INTENT(OUT) :: reffclws(klon, klev)! stratiform cloud droplet effective radius 
  REAL, INTENT(OUT) :: reffclwc(klon, klev)! convective cloud droplet effective radius 
  REAL, INTENT(OUT) :: cldnvi(klon)        ! column Integrated cloud droplet Number [/m2]
  REAL, INTENT(OUT) :: lcc3d(klon, klev)   ! cloud fraction for liquid part only [-]
  REAL, INTENT(OUT) :: lcc3dcon(klon, klev)! cloud fraction for liquid part only, convective clouds [-]
  REAL, INTENT(OUT) :: lcc3dstra(klon, klev)!cloud fraction for liquid part only, stratiform clouds [-]
  REAL, INTENT(OUT) :: icc3dcon(klon, klev)! cloud fraction for liquid part only, convective clouds [-]
  REAL, INTENT(OUT) :: icc3dstra(klon, klev)! cloud fraction for ice part only, stratiform clouds [-] 

  ! actual optical variables used as inputs for the radiative scheme
  REAL, INTENT(OUT) :: reliq(klon, klev)   ! liquid droplet effective radius [m] 
  REAL, INTENT(OUT) :: reice(klon, klev)   ! ice effective radius [m]
  REAL, INTENT(OUT) :: reliq_pi(klon, klev)! liquid droplet effective radius [m], pre-industrial
  REAL, INTENT(OUT) :: reice_pi(klon, klev)! ice effective radius [m], pre-industrial
  
  
  
  ! Local variables
  !----------------
  INTEGER flag_max

  ! threshold parameters
  REAL phase3d(klon, klev)
  REAL tcc(klon), ftmp(klon), lcc_integrat(klon), height(klon)
  LOGICAL lo
  INTEGER i, k
  REAL radius


  REAL rel, tc, rei, iwc, dei, deimin, deimax
  REAL k_ice
  REAL rhol ! density of liquid water in kg/m3
  REAL re_pi(klon, klev) ! cloud droplet effective radius [um] (pi value)

  REAL dzfice(klon,klev)
  REAL zclear(klon)
  REAL zcloud(klon)
  REAL zcloudh(klon)
  REAL zcloudm(klon)
  REAL zcloudl(klon)
  REAL rhodz(klon, klev) !--rho*dz of layer
  REAL zrho(klon, klev) !--rho of layer
  REAL dh(klon, klev) !--dz of layer
  REAL rad_chaud(klon, klev) !--radius for warm ("chaud") liquid clouds
  REAL rad_chaud_pi(klon, klev) !--radius for warm ("chaud") liquid clouds, pre-industrial
  REAL zflwp_var, zfiwp_var
  REAL d_rei_dt
!=====================================================================================

! Initialisation
!===============
  xflwp(:) = 0.D0
  xfiwp(:) = 0.D0
  xflwc(:,:) = 0.D0
  xfiwc(:,:) = 0.D0
  radocondwp(:) = 0.
  rhol=1000.0

  reliq(:,:) = 0.
  reice(:,:) = 0.
  reliq_pi(:,:) = 0.
  reice_pi(:,:) = 0.

! Preliminary calculations
!==========================


! for 'old' (pre-CMIP7) large-scale condensation scheme
! (firstilp), ice fraction is recomputed here
  IF ((.NOT. ok_new_lscp) .AND. iflag_t_glace.EQ.0) THEN
    DO k = 1, klev
      DO i = 1, klon
        icefrac_optics(i, k) = 1.0 - (temp(i,k)-t_glace_min_old)/(t_glace_max_old-t_glace_min_old)
        icefrac_optics(i, k) = min(max(icefrac_optics(i,k),0.0), 1.0)
      ENDDO
    ENDDO

  ELSE 
! ice fraction directly from the lscp param, except for convective grid point           
! where we take the temperature-dependent icefrac_optics computed in lmdz_call_cloud_optics

   DO k = 1, klev
      DO i = 1, klon
        IF ((.NOT. ptconv(i,k)) .AND. ok_new_lscp .AND. ok_icefra_lscp) THEN
           icefrac_optics(i,k)=picefra(i,k) ! picefra is the ice fraction computed in lscp
        ENDIF
      ENDDO
    ENDDO
  ENDIF

! computation of layers'mass and water contents for radiation
DO k = 1,klev
  DO i = 1,klon
    rhodz(i, k) = (paprs(i,k)-paprs(i,k+1))/rg ! kg/m2
    zrho(i, k) = pplay(i, k)/temp(i, k)/rd ! kg/m3
    dh(i, k) = rhodz(i, k)/zrho(i, k) ! m
    ! -Liquid/Ice water specific content, mesh averaged
    xflwc(i, k) = (1.-icefrac_optics(i,k))*radocond(i, k)
    xfiwc(i, k) = icefrac_optics(i, k)*radocond(i, k)
   ! vertically integrated contents (water paths)
    xflwp(i) = xflwp(i) + xflwc(i, k)*rhodz(i, k)
    xfiwp(i) = xfiwp(i) + xfiwc(i, k)*rhodz(i, k)
    radocondwp(i) = radocondwp(i) + radocond(i, k)*rhodz(i, k)
  END DO
END DO



! Computation of cloud droplet effective radius
!===============================================
! There 2 options to compute cloud droplet effective radius:
! if ok_cdnc: we compute cloud radius as a function of an in-cloud number concentration of cloud droplets (cdnc)
! depending on the concentration of soluble aerosols
! otherwise, cloud droplet radius is fixed to a constant value (in fact one constant for the first three layers, another
! one for layers above


! if ok_cdnc, let's first compute the in-cloud droplet number concentration

  IF (ok_cdnc) THEN
   
    ! Pre-industrial cloud droplet concentrations
    DO k = 1, klev
      DO i = 1, klon
        ! Formula "D" of Boucher and Lohmann, Tellus, 1995
        ! Cloud droplet number concentration (CDNC) is restricted
        ! to be within [20, 1000 cm^3]
        cdnc_pi(i, k) = 10.**(bl95_b0+bl95_b1*log(max(mass_solu_aero_pi(i,k), &
          1.E-4))/log(10.))*1.E6 !-m-3
        cdnc_pi(i, k) = min(cdnc_max_m3, max(cdnc_min_m3,cdnc_pi(i,k)))

      ENDDO
    ENDDO

   ! Present day cloud droplet concentrations
   IF (flag_aerosol .EQ. 7) THEN 

    ! flag_aerosol=7 => MACv2SP climatology 
    ! in this case we apply an enhancement factor dNovrN on the pi value
      DO k = 1, klev
        DO i = 1, klon
          cdnc(i, k) = cdnc_pi(i,k)*dNovrN(i)
        ENDDO
      ENDDO

   ELSE
   ! standard configuration using the same formula as above but
   ! considering present day aerosols concentrations
      DO k = 1, klev
        DO i = 1, klon
          cdnc(i, k) = 10.**(bl95_b0+bl95_b1*log(max(mass_solu_aero(i,k), &
            1.E-4))/log(10.))*1.E6 !-m-3
          cdnc(i, k) = min(cdnc_max_m3, max(cdnc_min_m3,cdnc(i,k)))
        ENDDO
      ENDDO

    ENDIF !--flag_aerosol

 ENDIF

! Cloud droplet effective radius calculation
! controled by ok_cdnc and iflag_cdreff

 IF (ok_cdnc .AND. iflag_cdreff .EQ. 0) THEN
    ! aerosol-aware formulation used until CMIP6
    ! Warning! the formula is erroneous as it
    ! considers the liq+ice water mass and 
    ! the mesh-averaged (and not the in-cloud)
    ! contents
    DO k = 1, klev
      DO i = 1, klon

        ! --pre-industrial case
        rad_chaud_pi(i, k) = 1.1*((radocond(i,k)*pplay(i, &
          k)/(rd*temp(i,k)))/(4./3.*rpi*rhol*cdnc_pi(i,k)))**(1./3.)
        rad_chaud_pi(i, k) = max(rad_chaud_pi(i,k)*1.E6, 5.)

        ! --present-day case
        rad_chaud(i, k) = 1.1*((radocond(i,k)*pplay(i, &
          k)/(rd*temp(i,k)))/(4./3*rpi*rhol*cdnc(i,k)))**(1./3.)
        rad_chaud(i, k) = max(rad_chaud(i,k)*1.E6, 5.)

        END DO
    ENDDO

 ELSE IF (ok_cdnc .AND. iflag_cdreff .EQ. 1) THEN
     ! similar as above but debugged

    DO k = 1, klev
      DO i = 1, klon

        ! --pre-industrial case
        rad_chaud_pi(i, k) = (xflwc(i,k)/max(pclc(i,k),seuil_neb)*pplay(i, &
          k)/(rd*temp(i,k))/(4./3.*rpi*rhol*cdnc_pi(i,k)))**(1./3.)
        rad_chaud_pi(i, k) = min(max(rad_chaud_pi(i,k)*1.E6, 5.),100.)

        ! --present-day case
        rad_chaud(i, k) = (xflwc(i,k)/max(pclc(i,k),seuil_neb)*pplay(i, &
          k)/(rd*temp(i,k))/(4./3*rpi*rhol*cdnc(i,k)))**(1./3.)
        rad_chaud(i, k) = min(max(rad_chaud(i,k)*1.E6, 5.),100.)

        END DO
    ENDDO

 ELSE ! ok_cdnc

    ! -fixed (prescribed) cloud droplet effective radius values
    DO k = 1, min(3, klev)
      DO i = 1, klon
        rad_chaud(i, k) = rad_chau2
        rad_chaud_pi(i, k) = rad_chau2
      ENDDO
    ENDDO
    DO k = min(3, klev) + 1, klev
      DO i = 1, klon
        rad_chaud(i, k) = rad_chau1
        rad_chaud_pi(i, k) = rad_chau1
      ENDDO
    ENDDO
 
 ENDIF ! ok_cdnc

  ! For output diagnostics of cloud droplet effective radius [um]
  ! we multiply here with f * xl (fraction of liquid water
  ! clouds in the grid cell) to avoid problems in the averaging of the output.
  ! The actual cloud droplet effective radius can be computed from outputs as re/fl

  DO k = 1, klev
    DO i = 1, klon

      reliq(i, k) = rad_chaud(i, k)
      reliq_pi(i, k) = rad_chaud_pi(i, k)     

      IF (pclc(i,k)<=seuil_neb) THEN

        fl(i, k) = seuil_neb*(1.-icefrac_optics(i,k))
        re(i, k) = rad_chaud(i, k)*fl(i, k)

      ELSE

        fl(i, k) = pclc(i, k)*(1.-icefrac_optics(i,k))
        re(i, k) = rad_chaud(i, k)*fl(i, k)
  
       ENDIF

    END DO
  END DO

! Computation of ice crystal effective radius
!=============================================

  DO k = 1, klev
    DO i = 1, klon

      IF (pclc(i,k)>seuil_neb) THEN

        ! Calculation of ice cloud effective radius in micron

        IF (iflag_rei .EQ. 2) THEN
            ! in-cloud ice water content in g/m3
            iwc = icefrac_optics(i,k) * radocond(i,k) / pclc(i,k) * zrho(i,k) * 1000.
            ! this formula is a simplified version of the Sun 2001 one (as in the IFS model,
            ! and which is activated for iflag_rei = 1).
            ! In particular, the term in temperature**2 has been simplified.
            ! The new coefs are tunable, and are by default set so that the results fit well
            ! to the Sun 2001 formula
            ! By default, rei_coef = 2.4 and rei_min_temp = 175.
            ! The ranges of these parameters are determined so that the RMSE between this
            ! formula and the one from Sun 2001 is less than 4 times the minimum RMSE
            ! The ranges are [1.9, 2.9] for rei_coef and [160., 185.] for rei_min_temp
            dei = rei_coef * (iwc**0.2445) * ( temp(i,k) - rei_min_temp )
            ! we clip the results
            deimin = 20.
            deimax = 155.
            dei = MIN(MAX(dei, deimin), deimax)
            ! formula to convert effective diameter to effective radius
            rei = 3. * SQRT(3.) / 8. * dei

        ELSEIF (iflag_rei .EQ. 1) THEN
            ! when we account for precipitation in the radiation scheme,
            ! we use the rei formula from Sun and Rikkus 1999 with a revision
            ! from Sun 2001 (as in the IFS model)
            iwc=icefrac_optics(i, k)*radocond(i, k)/pclc(i,k)*zrho(i,k)*1000. !in cloud ice water content in g/m3
            dei=(1.2351+0.0105*(temp(i,k)-273.15))*(45.8966*(iwc**0.2214) + &
               &0.7957*(iwc**0.2535)*(temp(i,k)-83.15))
            !deimax=155.0
            !deimin=20.+40*cos(abs(latitude_deg(i))/180.*RPI)
            !Etienne: deimax and deimin controled by rei_max and rei_min in physiq.def
            deimax=rei_max*2.0
            deimin=2.0*rei_min+40*cos(abs(latitude_deg(i))/180.*RPI) 
            dei=min(dei,deimax)
            dei=max(dei,deimin)
            rei=3.*sqrt(3.)/8.*dei
       
        ELSE
            ! Default
            ! for ice clouds: as a function of the ambiant temperature
            ! [formula used by Iacobellis and Somerville (2000), with an
            ! asymptotical value of 3.5 microns at T<-81.4 C added to be
            ! consistent with observations of Heymsfield et al. 1986]:
            ! 2011/05/24 : rei_min = 3.5 becomes a free PARAMETER as well as
            ! rei_max=61.29
           
            ! rei = ( rei_max - rei_min ) * T(°C) / 81.4 + rei_max
            ! to be used for a temperature in celcius T(°C) < 0
            ! rei=rei_min for T(°C) < -81.4
            ! Computation of slope for ice crystal effective radius=f(T)
            ! For consistency with original version, we impoe 0.71 when
            ! close to this value
            d_rei_dt = (rei_max-rei_min)/81.4
            IF (abs(d_rei_dt-0.71)<1.E-4) d_rei_dt = 0.71          
           
            tc = temp(i, k) - 273.15
            rei = d_rei_dt*tc + rei_max
            IF (tc<=-81.4) rei = rei_min

        ENDIF

      ELSE ! pclc > rneb

           rei = 0.

      ENDIF

      reice(i, k) = rei
      ! same radius for pi conditions
      reice_pi(i,k) = reice(i,k)

    ENDDO
  ENDDO

 

! Computation of cloud optical depth and emissivity
!===================================================

  DO k = 1, klev
    DO i = 1, klon

      IF (pclc(i,k)<=seuil_neb) THEN

        rel = 0.
        rei = 0.
        pcldtau(i, k) = 0.0
        pcldtaupi(i, k) = 0.0
        pclemi(i, k) = 0.0

      ELSE

        rel = rad_chaud(i, k)
        rei = reice(i,k)
        ! mass of in-cloud condensates in g
        zflwp_var = 1000.*(1.-icefrac_optics(i,k))*radocond(i, k)/pclc(i, k)*rhodz(i, k)
        zfiwp_var = 1000.*icefrac_optics(i, k)*radocond(i, k)/pclc(i, k)*rhodz(i, k)
        IF (zflwp_var==0.) rel = 1.
        IF (zfiwp_var==0. .OR. rei<=0.) rei = 1.
        ! -- cloud optical thickness :
        ! [for liquid clouds, traditional formula,
        ! for ice clouds, Ebert & Curry (1992)]       
        pcldtau(i, k) = 3.0/2.0*(zflwp_var/rel) & 
                    + zfiwp_var*(3.448E-03+2.431/ rei)
        IF (ok_cdnc) THEN
            pcldtaupi(i, k) = 3.0/2.0*zflwp_var/rad_chaud_pi(i, k) + &
                            zfiwp_var*(3.448E-03+2.431/rei)
        ELSE
        ! -- if cloud droplet radius is fixed, plcdtaupi = plcdtau
            pcldtaupi(i, k) = pcldtau(i,k)
        END IF
        ! -- cloud infrared emissivity:
        ! [the broadband infrared absorption coefficient is parameterized
        ! as a function of the effective cloud droplet radius]
        ! Ebert and Curry (1992) formula as used by Kiehl & Zender (1995):
        k_ice = k_ice0 + 1.0/rei
        pclemi(i, k) = 1.0 - exp(-coef_chau*zflwp_var-df*k_ice*zfiwp_var)

      ENDIF

    ENDDO
  ENDDO


! Cloud cover calculation 
! ========================

  DO i = 1, klon
    zclear(i) = 1.
    zcloud(i) = 0.
    zcloudh(i) = 0.
    zcloudm(i) = 0.
    zcloudl(i) = 0.
    pch(i) = 1.0
    pcm(i) = 1.0
    pcl(i) = 1.0

  ENDDO

  DO k=1, klev
     DO i=1,klon
       IF (pclc(i,k) <= seuil_neb) THEN
            pclc(i,k) = 0.
       END IF
     END DO
  END DO

  ! Cloud overlap approximation
  ! choix made through radopt.h
  ! novlp=1: max-random
  ! novlp=2: maximum
  ! novlp=3: random


  IF (novlp==1) THEN
    DO k = klev, 1, -1
      DO i = 1, klon
        zclear(i) = zclear(i)*(1.-max(pclc(i,k),zcloud(i)))/(1.-min(real( &
          zcloud(i),kind=8),1.-zepsec))
        pct(i) = 1. - zclear(i)
        IF (paprs(i,k)<prmhc) THEN
          pch(i) = pch(i)*(1.-max(pclc(i,k),zcloudh(i)))/(1.-min(real(zcloudh &
            (i),kind=8),1.-zepsec))
          zcloudh(i) = pclc(i, k)
        ELSE IF (paprs(i,k)>=prmhc .AND. paprs(i,k)<prlmc) THEN
          pcm(i) = pcm(i)*(1.-max(pclc(i,k),zcloudm(i)))/(1.-min(real(zcloudm &
            (i),kind=8),1.-zepsec))
          zcloudm(i) = pclc(i, k)
        ELSE IF (paprs(i,k)>=prlmc) THEN
          pcl(i) = pcl(i)*(1.-max(pclc(i,k),zcloudl(i)))/(1.-min(real(zcloudl &
            (i),kind=8),1.-zepsec))
          zcloudl(i) = pclc(i, k)
        ENDIF
        zcloud(i) = pclc(i, k)
      ENDDO
    ENDDO
  ELSE IF (novlp==2) THEN
    DO k = klev, 1, -1
      DO i = 1, klon
        zcloud(i) = max(pclc(i,k), zcloud(i))
        pct(i) = zcloud(i)
        IF (paprs(i,k)<prmhc) THEN
          pch(i) = min(pclc(i,k), pch(i))
        ELSE IF (paprs(i,k)>=prmhc .AND. paprs(i,k)<prlmc) THEN
          pcm(i) = min(pclc(i,k), pcm(i))
        ELSE IF (paprs(i,k)>=prlmc) THEN
          pcl(i) = min(pclc(i,k), pcl(i))
        ENDIF
      ENDDO
    ENDDO
  ELSE IF (novlp==3) THEN
    DO k = klev, 1, -1
      DO i = 1, klon
        zclear(i) = zclear(i)*(1.-pclc(i,k))
        pct(i) = 1 - zclear(i)
        IF (paprs(i,k)<prmhc) THEN
          pch(i) = pch(i)*(1.0-pclc(i,k))
        ELSE IF (paprs(i,k)>=prmhc .AND. paprs(i,k)<prlmc) THEN
          pcm(i) = pcm(i)*(1.0-pclc(i,k))
        ELSE IF (paprs(i,k)>=prlmc) THEN
          pcl(i) = pcl(i)*(1.0-pclc(i,k))
        ENDIF
      ENDDO
    ENDDO
  ENDIF

  DO i = 1, klon
    pch(i) = 1. - pch(i)
    pcm(i) = 1. - pcm(i)
    pcl(i) = 1. - pcl(i)
  ENDDO

  ! Diagnostics computation for CMIP protocol
  ! =========================================
  ! change by Nicolas Yan (LSCE)
  ! Cloud Droplet Number Concentration (CDNC) : 3D variable
  ! Fractionnal cover by liquid water cloud (LCC3D) : 3D variable
  ! Cloud Droplet Number Concentration at top of cloud (CLDNCL) : 2D variable
  ! Droplet effective radius at top of cloud (REFFCLWTOP) : 2D variable
  ! Fractionnal cover by liquid water at top of clouds (LCC) : 2D variable

  IF (ok_cdnc) THEN

    DO k = 1, klev
      DO i = 1, klon
        phase3d(i, k) = 1 - icefrac_optics(i, k)
        IF (pclc(i,k)<=seuil_neb) THEN
          lcc3d(i, k) = seuil_neb*phase3d(i, k)
        ELSE
          lcc3d(i, k) = pclc(i, k)*phase3d(i, k)
        ENDIF
        scdnc(i, k) = lcc3d(i, k)*cdnc(i, k) ! m-3
      ENDDO
    ENDDO

    DO i = 1, klon
      lcc(i) = 0.
      reffclwtop(i) = 0.
      cldncl(i) = 0.
      IF (novlp.EQ.3 .OR. novlp.EQ.1) tcc(i) = 1.
      IF (novlp.EQ.2) tcc(i) = 0.
    ENDDO

    DO i = 1, klon
      DO k = klev - 1, 1, -1 !From TOA down

          ! Test, if the cloud optical depth exceeds the necessary
          ! threshold:

        IF (pcldtau(i,k)>thres_tau .AND. pclc(i,k)>thres_neb) THEN

          IF (novlp.EQ.2) THEN
            IF (first_first) THEN
              first(i,k) = .TRUE.
            ENDIF
            flag_max = -1.
            ftmp(i) = max(tcc(i), pclc(i,k))
          ENDIF

          IF (novlp.EQ.3) THEN
            IF (first_first) THEN
              first(i,k) = .TRUE.
            ENDIF
            flag_max = 1.
            ftmp(i) = tcc(i)*(1-pclc(i,k))
          ENDIF

          IF (novlp.EQ.1) THEN
            IF (first_first) THEN
              first(i,k) = .TRUE.
            ENDIF
            flag_max = 1.
            ftmp(i) = tcc(i)*(1.-max(pclc(i,k),pclc(i,k+1)))/(1.-min(pclc(i, &
              k+1),1.-thres_neb))
          ENDIF
          ! Effective radius of cloud droplet at top of cloud (m)
          reffclwtop(i) = reffclwtop(i) + rad_chaud(i, k)*1.0E-06*phase3d(i, &
            k)*(tcc(i)-ftmp(i))*flag_max
          ! CDNC at top of cloud (m-3)
          cldncl(i) = cldncl(i) + cdnc(i, k)*phase3d(i, k)*(tcc(i)-ftmp(i))* &
            flag_max
          ! Liquid Cloud Content at top of cloud
          lcc(i) = lcc(i) + phase3d(i, k)*(tcc(i)-ftmp(i))*flag_max
          ! Total Cloud Content at top of cloud
          tcc(i) = ftmp(i)

        ENDIF ! is there a visible, not-too-small cloud?
      ENDDO ! loop over k

      IF (novlp.EQ.3 .OR. novlp.EQ.1) tcc(i) = 1. - tcc(i)

    ENDDO ! loop over i

    ! Convective and Stratiform Cloud Droplet Effective Radius (REFFCLWC, REFFCLWS)
    DO i = 1, klon
      DO k = 1, klev
        ! Weight to be used for outputs: eau_liquide*couverture nuageuse
        lcc3dcon(i, k) = rnebcon(i, k)*phase3d(i, k)*ccwcon(i, k) ! eau liquide convective
        lcc3dstra(i, k) = pclc(i, k)*radocond(i, k)*phase3d(i, k)
        lcc3dstra(i, k) = lcc3dstra(i, k) - lcc3dcon(i, k) ! eau liquide stratiforme
        lcc3dstra(i, k) = max(lcc3dstra(i,k), 0.0)
        icc3dcon(i, k) = rnebcon(i, k)*(1-phase3d(i, k))*ccwcon(i, k) !  glace convective
        icc3dstra(i, k)= pclc(i, k)*radocond(i, k)*(1-phase3d(i, k))
        icc3dstra(i, k) = icc3dstra(i, k) - icc3dcon(i, k) ! glace stratiforme
        icc3dstra(i, k) = max( icc3dstra(i, k), 0.0)

        ! Compute cloud droplet radius as above in meter
        radius = 1.1*((radocond(i,k)*pplay(i,k)/(rd*temp(i,k)))/(4./3*rpi*1000.* &
          cdnc(i,k)))**(1./3.)
        radius = max(radius, 5.E-6)
        ! Convective Cloud Droplet Effective Radius (REFFCLWC) : variable 3D
        reffclwc(i, k) = radius
        reffclwc(i, k) = reffclwc(i, k)*lcc3dcon(i, k)
        ! Stratiform Cloud Droplet Effective Radius (REFFCLWS) : variable 3D
        reffclws(i, k) = radius
        reffclws(i, k) = reffclws(i, k)*lcc3dstra(i, k)
      ENDDO !klev
    ENDDO !klon

    ! Column Integrated Cloud Droplet Number (CLDNVI) : variable 2D

    DO i = 1, klon
      cldnvi(i) = 0.
      lcc_integrat(i) = 0.
      height(i) = 0.
      DO k = 1, klev
        cldnvi(i) = cldnvi(i) + cdnc(i, k)*lcc3d(i, k)*dh(i, k)
        lcc_integrat(i) = lcc_integrat(i) + lcc3d(i, k)*dh(i, k)
        height(i) = height(i) + dh(i, k)
      ENDDO ! klev
      lcc_integrat(i) = lcc_integrat(i)/height(i)
      IF (lcc_integrat(i)<=1.0E-03) THEN
        cldnvi(i) = cldnvi(i)*lcc(i)/seuil_neb
      ELSE
        cldnvi(i) = cldnvi(i)*lcc(i)/lcc_integrat(i)
      ENDIF
    ENDDO ! klon

    DO i = 1, klon
      DO k = 1, klev
        IF (scdnc(i,k)<=0.0) scdnc(i, k) = 0.0
        IF (reffclws(i,k)<=0.0) reffclws(i, k) = 0.0
        IF (reffclwc(i,k)<=0.0) reffclwc(i, k) = 0.0
        IF (lcc3d(i,k)<=0.0) lcc3d(i, k) = 0.0
        IF (lcc3dcon(i,k)<=0.0) lcc3dcon(i, k) = 0.0
        IF (lcc3dstra(i,k)<=0.0) lcc3dstra(i, k) = 0.0
        IF (icc3dcon(i,k)<=0.0) icc3dcon(i, k) = 0.0
        IF (icc3dstra(i,k)<=0.0) icc3dstra(i, k) = 0.0
      ENDDO
      IF (reffclwtop(i)<=0.0) reffclwtop(i) = 0.0
      IF (cldncl(i)<=0.0) cldncl(i) = 0.0
      IF (cldnvi(i)<=0.0) cldnvi(i) = 0.0
      IF (lcc(i)<=0.0) lcc(i) = 0.0
    ENDDO

  ENDIF !ok_cdnc

  RETURN

END SUBROUTINE cloud_optics_prop

END MODULE lmdz_cloud_optics_prop
